July 2004
TRADERS' TIPS
Here is this month's selection of Traders' Tips, contributed by various
developers of technical analysis software to help readers more easily implement
some of the strategies presented in this and other issues.
You can copy these formulas and programs for easy use in your spreadsheet
or analysis software. Simply "select" the desired text by highlighting
as you would in any word processing program, then use your standard key
command for copy or choose "copy" from the browser menu. The copied text
can then be "pasted" into any open spreadsheet or other software by selecting
an insertion point and executing a paste command. By toggling back and
forth between an application window and the open webpage, data can be transferred
with ease.
This month's tips include formulas and programs for:
TRADESTATION: VFI PERFORMANCE
METASTOCK: VFI PERFORMANCE
AMIBROKER: VFI PERFORMANCE
eSIGNAL: VFI PERFORMANCE
WEALTH-LAB: VFI PERFORMANCE
TRADINGSOLUTIONS: VFI PERFORMANCE
NEUROSHELL TRADER: VFI PERFORMANCE
NEOTICKER: VFI PERFORMANCE
STOCKWIZ: VFI PERFORMANCE
TECHNIFILTER PLUS: VFI PERFORMANCE
or return to July 2004 Contents
TRADESTATION:
VFI PERFORMANCE
Markos Katsanos' article in this issue, "Volume Flow Indicator Performance,"
provides four strategies for trading the volume flow indicator (VFI). All
four strategies are provided here in TradeStation EasyLanguage. In addition,
Katsanos introduced a new indicator, the VFI-price divergence, which is
also coded here.
Most of the calculations are performed in the function "VfiSmoothed,"
which was given in the TradeStation tip in the May 2004 Traders' Tips column.
When using these strategies, please remember to format your strategy
properly for the maximum number of bars the study may reference. These
strategies need to review a fairly large number of bars, so I used 250
bars.
Indicator: VFI-Price Divergence
inputs:
Coef( .2 ),
VCoef( 2.5 ),
Period( 130 ),
VFISmoothing( 3 ),
LinearRegPeriod( 120 ) ;
variables:
oCutOff( 0 ), { calculated volume cutoff }
oVC( 0 ), { trimmed volume values }
oMF( 0 ), { difference in 'typical' price }
oVFI( 0 ), { calculated VFI }
MySmoothedVFI( 0 ), { smoothed VFI values }
MyVolume( 0 ), { volume after BarInterval test }
LRS( 0 ), { linear regression slope - price }
LRSI( 0 ), { linear regression slope - VFI }
KatsanosDivergence( 0 ),
LowestVFI( 9999999 ),
VFI1( 0 ); { always positive VFI }
MyVolume = iff( BarType < 2, Ticks, Volume ) ;
MySmoothedVFI = VFISmooth( Coef, VCoef, Period,
VFISmoothing, MyVolume, oCutOff, oVC, oMF, oVFI ) ;
if MySmoothedVFI < LowestVFI then
LowestVFI = MySmoothedVFI ;
VFI1 = MySmoothedVFI + AbsValue( LowestVFI )+ 10 ;
if Currentbar > LinearRegPeriod * 2 then
begin
if Close[ LinearRegPeriod ] > 0 then
LRS = LinearRegSlope( close , LinearRegPeriod )
/ close[ LinearRegPeriod ] * 100 ;
if VFI1[ LinearRegPeriod ] > 0 then
LRSI= LinearRegSlope( VFI1, LinearRegPeriod )
/ VFI1[ LinearRegPeriod ] * 100 ;
KatsanosDivergence =
XAverage( LRSI - LRS, 3 ) * 100 ;
Plot1( KatsanosDivergence ) ;
end ;
Strategy: Katsanos VFI Cross 0
inputs:
Coef( .2 ),
VCoef( 2.5 ),
Period( 5 ),
SmoothedPeriod( 7 ) ;
variables:
oCutOff( 0 ),
oVC( 0 ),
oMF( 0 ),
oVFI( 0 ),
MyVFI( 0 ),
MyVolume( 0 ) ;
MyVolume = iff( BarType < 2, Ticks, Volume ) ;
MyVFI = VFISmooth( Coef, VCoef, Period,
SmoothedPeriod, MyVolume, oCutOff, oVC, oMF, oVFI );
if MyVFI crosses over 0 then
buy next bar at market ;
if MyVFI crosses under 0 then
sellshort next bar at market ;
Strategy: Katsanos VFI Divergence inputs:
Coef( .2 ),
VCoef( 2.5 ),
Period( 130 ),
VFISmoothing( 3 ),
LinearRegPeriod( 120 ),
TradeThreshold( 100 ) ;
variables:
oCutOff( 0 ), { calculated volume cutoff }
oVC( 0 ), { trimmed volume values }
oMF( 0 ), { difference in 'typical' price }
oVFI( 0 ), { calculated VFI}
MySmoothedVFI( 0 ), { smoothed VFI values }
MyVolume( 0 ), { volume after BarInterval test }
LRS(0), {linear regression slope - normalized price}
LRSI(0), {linear regression slope - normalized VFI}
KatsanosDivergence( 0 ),
LowestVFI( 9999999 ),
VFI1( 0 ) ; { always positive VFI }
MyVolume = iff( BarType < 2, Ticks, Volume ) ;
MySmoothedVFI = VFISmooth( Coef, VCoef, Period,
VFISmoothing , MyVolume, oCutOff, oVC, oMF, oVFI ) ;
if MySmoothedVFI < LowestVFI then
LowestVFI = MySmoothedVFI ;
VFI1 = MySmoothedVFI + AbsValue( LowestVFI ) + 10 ;
if Currentbar > LinearRegPeriod * 2 then
begin
if Close[ LinearRegPeriod ] > 0 then
LRS = LinearRegSlope( Close , LinearRegPeriod )
/ Close[ LinearRegPeriod ]*100 ;
if VFI1[ LinearRegPeriod ] > 0 then
LRSI = LinearRegSlope( VFI1, LinearRegPeriod )
/ VFI1[ LinearRegPeriod ]*100 ;
KatsanosDivergence =
XAverage( LRSI - LRS, 3 ) * 100 ;
end ;
{ enter long }
if KatsanosDivergence[ 1 ] > TradeThreshold
and KatsanosDivergence[ 1 ] > KatsanosDivergence
and LRSI > 0
then
Buy next bar at Market ;
{ exit long }
if KatsanosDivergence < 0 and LRSI < 0 then
Sell next bar at Market ;
Strategy: Katsanos VFI Pattern inputs:
VFIEnterL( -2 ),
MA( 40 ),
LRPeriod( 20 ),
LRC( 30 ),
UB( .1 ),
LB( -.05 ),
VFIExitAngle( -40 ),
VFIExitL( -2 ),
Coef( .2 ),
VCoef( 2.5 ),
Period( 130 ),
VFISmoothing( 3 ) ;
variables:
oCutOff( 0 ),
oVC( 0 ),
oMF( 0 ),
oVFI( 0 ),
MySmoothedVFI( 0 ),
MyVolume( 0 ) ;
MyVolume = iff( BarType < 2, Ticks, Volume ) ;
MySmoothedVFI = VFISmooth( Coef, VCoef, Period,
VFISmoothing, MyVolume, oCutOff, oVC, oMF, oVFI ) ;
if BarNumber > 2 * Period then
begin
if MarketPosition = 0
and oVFI > VFIEnterL
and LinearRegAngleFC( oVFI, LRPeriod ) > 0
and oVFI > XAverage( oVFI, MA )
and LinearRegSlopeFC( C, LRC ) < UB
* LinearRegValue( C , LRC, LRC - 1 ) / 100
and LinearRegSlopeFC( C, LRC ) > LB
* LinearRegValue( C, LRC, LRC - 1 ) / 100
then
Buy ( "BUY" ) next bar at market ;
if LinearRegAngle( oVFI, LRPeriod ) < VFIExitAngle
or oVFI < VFIExitL
then
Sell ( "VFI EXIT" ) next bar at market ;
end ;
Strategy: Katsanos VFI MA Cross Inputs:
Coef( .2 ),
VCoef( 2.5 ),
Period( 1305 ),
SmoothedPeriod( 3 ),
LongVFILen( 25 ),
ShortVFILen( 11 ) ;
variables:
oCutOff( 0 ),
oVC( 0 ),
oMF( 0 ),
oVFI( 0 ),
MyVFI( 0 ),
MyVolume( 0 ),
LongMA( 0 ),
ShortMA( 0 ) ;
MyVolume = iff( BarType < 2, Ticks, Volume ) ;
MyVFI = VFISmooth( Coef, VCoef, Period, SmoothedPeriod,
MyVolume, oCutOff, oVC, oMF, oVFI ) ;
LongMA = XAverage( MyVFI, LongVFILen ) ;
ShortMA = XAverage( MyVFI, ShortVFILen ) ;
if ShortMA crosses over LongMA then
buy next bar at market ;
if LongMA crosses over ShortMA then
sell next bar at market ;
This EasyLanguage code will be posted in the file library at www.TradeStationWorld.com.
Look for the file "VFI Performance.Eld." A sample chart is in Figure 1.
FIGURE 1: TRADESTATION, VFI-PRICE DIVERGENCE. This sample
TradeStation chart shows Markos Katsanos' volume flow indicator on Foamex
International (FMXI) along with the VFI-price divergence indicator.
--Mark Mills
MarkM@TSSec at www.TradeStationWorld.com
EasyLanguage Questions Forum
TradeStation Securities, Inc.
A subsidiary of TradeStation Group, Inc.
GO BACK
METASTOCK: VFI PERFORMANCE
See the sidebar in Markos Katsanos' article in this issue for MetaStock
code for implementing the volume flow indicator, which Katsanos provided
as part of his article.
--William Golson
Equis International
GO BACK
AMIBROKER: VFI PERFORMANCE
In "Volume Flow Indicator Performance," Markos Katsanos compares the
results of CFI-based trading systems to OBV-based systems. All the systems
presented in the article can be recreated using AmiBroker.
Listing 1 shows code that implements all four systems. The formula should
be applied in AmiBroker's Automatic Analysis window. You can choose the
test you would like to run by clicking on the "Parameters" button. Please
do not forget to go to the "Settings" dialog to adjust backtesting parameters,
such as commissions, bar interval, and so on. After that, click the "Back
test" button to perform the system test. In less than a second, the backtest
will be complete. Then you can choose "Show arrows for actual trades" to
show the buy/sell arrows and get detailed statistics, including the well-known
Sharpe ratio, ulcer index, and many others, by clicking on the "Report"
button.
FIGURE 2: AMIBROKER, VOLUME FLOW INDICATOR. This AmiBroker
screenshot shows a weekly price chart of GLW [Corning Inc.] with buy (green
arrow) and sell (red arrow) signals generated by the VFI formula (upper
pane) and the 26-week VFI indicator with its seven-bar EMA plus color-coded
volume bars in the lower pane.
In AmiBroker, you can run not only individual backtests but also
a full portfolio-level backtest. For that, you would need to "uncomment"
position sizing in the formula below.
LISTING 1
// You can choose from one of the following types of tests
// 1 - VFI level (weekly)
// 2 - Divergence
// 3 - Break from base
// 4 - MA crossover
TestType = Param("TestType", 1, 1, 4, 1 );
function VFI( Period, VCoef )
{
Coef = 0.2;
inter = log( Avg ) - log( Ref( Avg, -1 ) );
Vinter = StDev(inter, 30 );
Cutoff = Coef * Vinter * Close;
Vave = Ref( MA( V, Period ), -1 );
Vmax = Vave * Vcoef;
Vc = Min( V, VMax );
MF = Avg - Ref( Avg, -1 );
VCP = IIf( MF > Cutoff, VC, IIf ( MF < -Cutoff, -VC, 0 ) );
VFIv = Sum( VCP , Period )/Vave;
VFIv = EMA( VFIv, 3 );
return VFIv;
}
// use 26 weeks for test 1, and 130 days otherwise
Period = IIf( TestType == 1, 26, 130 );
VCoef = 2.5;
VF = VFI( Period, VCoef );
if( TestType == 1 )
{
// VFI level (weekly)
Buy = EMA( VF, 7 ) > 0.01;
Sell = EMA( VF, 7 ) < 0;
}
if( TestType == 2 )
{
// VFI divergence
D1 = 120; //Optimize( "DivDays", 120, 50, 300, 1 );
P1 = VF + abs( Lowest( VF ) ) + 10;
LRSI = LinRegSlope( P1, D1 ) / abs( Ref( P1, -D1 ) ) * 100;
LRS = LinRegSlope( C, D1 ) / abs( Ref( C, -D1 ) ) * 100;
DIVERG = LRSI - LRS;
DIVERG = EMA( DIVERG, 3 ) * 100;
Buy = Ref( Diverg, -1 ) > 100 AND Diverg < Ref( Diverg, -1 ) AND LRSI > 0;
Sell = Diverg < 0 OR LRSI < 0;
}
if( TestType == 3 )
{
// VFI break from base
Buy = VF > -2 AND LinRegSlope( VF, 20 ) > 0.1 AND
VF > EMA( VF, 40 ) AND
LinRegSlope( C, 30 ) < Ref( C, -30 ) * 0.6 / 100 AND
LinRegSlope( C, 30 ) > 0;
Sell = VF < -2 OR LinRegSlope( VF, 20 ) < -0.8;
}
if( TestType == 4 )
{
// VFI MA crossover
SMA = EMA( VF, Optimize("SMA", 11, 2, 20, 1 ) );
LMA = EMA( VF, Optimize("LMA", 25, 10, 40, 1 ) );
Buy = Cross( SMA, LMA );
Sell = Cross( LMA, SMA );
}
// Position sizing
// uncomment 2 lines below to invest max 20% to single security
// PositionSize = -20;
// SetOption("MaxOpenPositions", 5 );
Here is the WealthScript code:
{ VFI Long & Short ChartScript }
{$I 'VFI'}
const UseTrend = true; // Use 'false' for zero crossings only
const SwingPts = 4;
var Bar, StartBar, p, VFIema, VFIPane, EntryBar, PTBar1, PTBar2: integer;
var Projected: float;
var Found, bLongSAR: boolean;
{ PeakSupport/TroughSupport find the peaks/trough for the trend line }
procedure TroughSupport( Bar, EntryBar, TestSer: integer );
begin
PTBar1 := TroughBar( EntryBar, TestSer, SwingPts );
PTBar2 := TroughBar( Bar, TestSer, SwingPts );
Found := PTBar2 <> PTBar1;
end;
procedure PeakSupport( Bar, EntryBar, TestSer: integer );
begin
PTBar1 := PeakBar( EntryBar, TestSer, SwingPts );
PTBar2 := PeakBar( Bar, TestSer, SwingPts );
Found := PTBar2 <> PTBar1;
end;
{ This exit routine also resets variables and draws the VFI trend line }
procedure ExitTrade( Bar, p, Color: integer; IsLong: boolean; SignalName: string );
begin
Found := false;
SetBackgroundColor( Bar, Color );
if SignalName = 'TrendX' then
DrawLine( PTBar1, @VFIema[PTBar1], Bar, @VFIema[Bar], VFIPane, #Red, #Thin );
if IsLong then
SellAtMarket( Bar + 1, p, SignalName )
else
CoverAtMarket( Bar + 1, p, SignalName );
end;
{ Script execution begins here }
SetPeakTroughMode( #AsPoint );
UseUpdatedEMA( true );
if IsWeekly then
begin
VFIema := EMASeries( VFISeries( 26, 3, 0.2, 2.5 ), 7 );
StartBar := 89;
end else
begin
VFIema := EMASeries( VFISeries( 130, 3, 0.2, 2.5 ), 40 );
StartBar := 300;
end;
VFIPane := CreatePane( 125, false, true );
PlotSeriesLabel( VFIema, VFIPane, #Teal, #Thick, 'EMA(VFI)' );
DrawHorzLine( 0, VFIPane, #Black, #Dotted );
for Bar := StartBar to BarCount - 1 do
begin
if LastPositionActive then { Exit Rules }
begin
p := LastPosition;
bLongSAR := PositionLong( p );
EntryBar := PositionEntryBar( p );
{ Exit on zero-crossing or trend break, whichever is first }
if bLongSAR then
begin
if not Found then
TroughSupport( Bar, EntryBar, VFIema );
if CrossUnderValue( Bar, VFIema, 0 ) then
ExitTrade( Bar, p, #RedBkg, bLongSAR, 'ZeroX' )
else if Found and UseTrend then
begin
Projected := LineExtendY( PTBar1, @VFIema[PTBar1], PTBar2, @VFIema[PTBar2], Bar );
if @VFIema[Bar] < Projected then
ExitTrade( Bar, p, #BlueBkg, bLongSAR, 'TrendX' );
end;
end
else
begin
if not Found then
PeakSupport( Bar, EntryBar, VFIema );
if CrossOverValue( Bar, VFIema, 0 ) then
ExitTrade( Bar, p, #RedBkg, bLongSAR, 'ZeroX' )
else if Found and UseTrend then
begin
Projected := LineExtendY( PTBar1, @VFIema[PTBar1], PTBar2, @VFIema[PTBar2], Bar );
if @VFIema[Bar] > Projected then
ExitTrade( Bar, p, #BlueBkg, bLongSAR, 'TrendX' );
end;
end;
end;
{ Entry logic }
if not bLongSAR then
if CrossOverValue( Bar, VFIema, 0 ) then
BuyAtMarket( Bar + 1, '' );
if bLongSAR then
if CrossUnderValue( Bar, VFIema, 0 ) then
ShortAtMarket( Bar + 1, '' );
end;
-- Robert Sucher, Wealth-Lab, Inc.
www.wealth-lab.com
GO BACK
TRADINGSOLUTIONS: VFI PERFORMANCE
In his article "Volume Flow Indicator Performance," Markos Katsanos
presents several entry/exit systems for testing the performance of the
volume flow indicator, which he introduced in the June 2004 issue.
As a reminder, the calculation of the volume flow indicator (VFI) is
as follows:
Name: Volume Flow Indicator
Short Name: VFI
Inputs: Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff
Formula:
EMA (Div (Sum (If (GT (Abs (Change (Typical (Close,High,Low),1)), Mult3 (0.2, StDev
(Change (Ln (Typical (Close, High, Low)),1),30), Close)), Mult (Min (Volume, Mult
(Lag (MA (Volume, Period for VFI),1), Maximum Volume Cutoff)), Sign (Change (Typical
(Close, High, Low),1))),0), Period for VFI), Lag (MA (Volume, Period for VFI),1)),3)
This month's article introduces a new indicator, the divergence
LRS indicator. A subvalue of this, called LRSI, is also used directly from
entry/exit systems. Here is the calculation of these indicators:
Name: Lowest From Beginning
Short Name: LowestFB
Inputs: Value
Formula:
If (IsNull (Lag (Value, 1)), Value, Min (Value, Prev (1)))
Name: VFI LRS Indicator
Short Name: VFILRSI
Inputs: Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff, Days for Divergence
Formula:
Mult (Div (Slope (Add3 (VFI (Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff),
Abs (LowestFB (VFI (Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff))), 10),
Days for Divergence), Abs (Lag (Add3 (VFI (Close, High, Low, Volume, Period for VFI,
Maximum Volume Cutoff), Abs (LowestFB (VFI (Close, High, Low, Volume, Period for VFI,
Maximum Volume Cutoff))), 10), Days for Divergence))), 100)
Name: Divergence LRS Indicator
Short Name: Diverg
Inputs: Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff, Days for Divergence
Formula:
Mult (EMA (Sub (VFILRSI (Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff,
Days for Divergence), Mult (Div (Slope (Close, Days for Divergence), Abs (Lag (Close,
Days for Divergence))), 100)), 3), 100)
Katsanos' article introduces four different entry/exit systems for
testing the viability of the VFI and comparing it to on-balance volume
(OBV).
Name: VFI Test1. VFI>0
Inputs: Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff
Enter Long:
1. GT(EMA(VFI (Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff), 7, 0)
Exit Long:
1. LT(EMA(VFI (Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff), 7, 0)
Name: VFI Test2. Divergence
Inputs: Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff, Days for Divergence
Enter Long (when ALL true):
1. GT(Lag(Diverg(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff,
Days for Divergence), 1), 100)
2. LT(Diverg(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff,
Days for Divergence), Lag(Diverg(Close, High, Low, Volume, Period for VFI,
Maximum Volume Cutoff, Days for Divergence), 1)
3. GT(VFILRSI(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff,
Days for Divergence), 0)
Exit Long (when ANY true):
1. LT(Diverg(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff,
Days for Divergence), 0)
2. LT(VFILRSI(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff,
Days for Divergence), 0)
Name: VFI Test3. Break from base (VFI)
Inputs: Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff
Enter Long (when ALL true):
1. GT(VFI(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff), -2)
2. GT(Slope(VFI(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff), 20), 0.1)
3. GT(VFI(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff),
EMA(VFI(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff), 40))
4. LT(Slope(Close, 30), Div(Mult(Lag(Close, 30), 0.6), 100))
5. GT(Slope(Close, 30)
Exit Long (when ANY true):
1. LT(VFI(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff), -2)
2. LT(Slope(VFI(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff), 20), -0.8)
Name: VFI Test3. Break from base (OBV)
Inputs: Close, Volume
Enter Long (when ALL true):
1. GT(Slope(OBV(Close, Volume), 20), 0.1)
2. GT(OBV(Close, Volume), EMA(OBV(Close, Volume), 40))
3. LT(Slope(Close, 30), Div(Mult(Lag(Close, 30), 0.6), 100))
4. GT(Slope(Close, 30)
Exit Long (when ANY true):
1. LT(Slope(OBV(Close, Volume), 20), -0.8)
Name: VFI Test4. MA crossover
Inputs: Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff,
Short EMA Period, Long EMA Period
Enter Long:
1. CrossAbove(EMA(VFI(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff),
Short EMA Period), EMA(VFI(Close, High, Low, Volume, Period for VFI,
Maximum Volume Cutoff), Long EMA Period))
Exit Long:
1. CrossAbove(EMA(VFI(Close, High, Low, Volume, Period for VFI, Maximum Volume Cutoff),
Long EMA Period), EMA(VFI(Close, High, Low, Volume, Period for VFI,
Maximum Volume Cutoff), Short EMA Period))
These functions are available in a function file that can be downloaded
from the TradingSolutions website (www.tradingsolutions.com) in the Solution
Library section. As with many indicators, indicators and systems such as
these can make good inputs to neural network predictions.
--Gary Geniesse
NeuroDimension, Inc.
800 634-3327, 352 377-5144
https://www.tradingsolutions.com
GO BACK
NEUROSHELL TRADER: VFI PERFORMANCE
The trading systems described by Markos Katsanos in "Volume Flow Indicator
Performance" are easily implemented in NeuroShell Trader. It should be
noted that these systems use the VFI custom indicator, which was described
in last month's Traders' Tips.
Test 1: indicator level
To recreate the first test -- the indicator level trading system -- for
the volume flow indicator in NeuroShell Trader, select "New Trading Strategy
..." from the Insert menu and enter the following long entry and exit conditions
in the appropriate locations of the Trading Strategy Wizard:
Generate a buy long MARKET order if ALL of the following are true:
CrossAbove ( ExpAvg ( VFI, 7), 0)
Generate a sell long MARKET order if ALL of the following are true:
CrossBelow ( ExpAvg ( VFI, 7), 0)
Test 2: divergence
To implement the second test--the divergence trading system--in NeuroShell
Trader, you should first create the divergence indicator in a chart and
then create a Trading Strategy based on that indicator and its components.
To recreate the divergence indicator, select "New Indicator ..." from the
Insert menu and use the Indicator Wizard to create each of the following:
LRS:
Divide ( LinRegSlope ( Close, 120 ), Lag ( Close, 120 ) )
LRSI:
Divide ( LinRegSlope ( VFI, 120 ), Lag ( VFI, 120 ) )
DIVERGENCE:
Multiply2 ( ExpAvg ( Subtract ( LRSI, LRS ), 3 ), 100 )
To recreate the divergence trading system test for the volume flow
indicator in NeuroShell Trader, select "New Trading Strategy ..." from the
Insert menu and enter the following long entry and exit conditions in the
appropriate locations of the Trading Strategy Wizard:
Generate a buy long MARKET order if ALL of the following are true:
A>B ( Lag ( DIVERGENCE, 1 ), 100 )
A<B ( DIVERGENCE, Lag ( DIVERGENCE, 1 ) )
A>B ( LRSI, 0 )
Generate a sell long MARKET order if ONE of the following are true:
A<B ( DIVERGENCE, 0 )
A<B ( LRSI, 0 )
Test 3: Break from base
To recreate the third test -- the break from base trading system -- for
the volume flow indicator in NeuroShell Trader, select "New Trading Strategy
..." from the Insert menu and enter the following long entry and exit conditions
in the appropriate locations of the Trading Strategy Wizard:
Generate a buy long MARKET order if ALL of the following are true:
A>B ( VFI, -2 )
A>B ( LinRegSlope ( VFI, 20 ), 0.1 )
A>B ( VFI, ExpAvg ( VFI, 40 ) )
A<B ( LinRegSlope ( Close, 30 ), Multiply ( 0.006, Lag ( Close, 30 ) ) )
A>B ( LinRegSlope ( Close, 30 ), 0 )
Generate a sell long MARKET order if ONE of the following are true:
A<B ( LinRegSlope (VFI, 20), -0.8 )
A<B ( VFI, -2 )
Test 4: Indicator direction
To recreate test 4 -- the indicator direction trading system -- for the
volume flow indicator in NeuroShell Trader, select "New Trading Strategy
..." from the Insert menu and enter the following long entry and exit conditions
in the appropriate locations of the Trading Strategy Wizard:
Generate a buy long MARKET order if ALL of the following are true:
ExpAvgCrossAbove (VFI, 11, 25 ) )
Generate a sell long MARKET order if ALL of the following are true:
ExpAvgCrossBelow (VFI, 11, 25 ) )
Users of NeuroShell Trader can go to the STOCKS & COMMODITIES
section of the NeuroShell Trader free technical support website to download
a sample chart that includes the volume flow custom indicator (Figure 6).
FIGURE 6: NEUROSHELL TRADER, VOLUME FLOW INDICATOR.
Here's a sample chart in NeuroShell Trader displaying all four trading
strategies discussed by Markos Katsanos in his article this issue. The
techniques implement the volume flow indicator.
--Marge Sherald, Ward Systems Group, Inc.
301 662-7950, sales@wardsystems.com
www.neuroshell.com
GO BACK
NEOTICKER: VFI PERFORMANCE
The NeoTicker Backtest EZ power indicator will allow users to implement
the four testing systems presented in "Volume Flow Indicator Performance"
by Markos Katsanos in this issue, with just a few lines of formula.
Test 1: Indicator level
The first test requires no additional indicator programming. To start
the test, first add the Backtest EZ indicator to the weekly data series.
At the "Add indicator" window in Long Entry and Long Exit field, enter
the corresponding formula (Listing 1). At the "System" tab, change initial
capital, interest, commission, and testing date range according to the
article's criteria. After all the information is filled in, press Apply
at the "Add indicator" window to start the system calculation. After the
calculation is completed, NeoTicker Backtest EZ plots the equity curve
of the VFI crossover zero system (Figure 7). Right-click on this equity
curve to access the NeoTicker built-in system statistic report presented
in the System Performance Viewer.
FIGURE 7: NEOTICKER, VOLUME FLOW INDICATOR. After the
calculation is completed, NeoTicker Backtest EZ plots the equity curve
of the VFI crossover zero system.
Test 2: Divergence
This test requires an additional indicator called the divergence LRS
indicator (Listing 2). This indicator returns two plots. This indicator
has one integer parameter, divergence period. The first plot is divergence;
the second plot is LRSI. These two values are returned because the divergence
system requires these two calculations.
After the divergence LRS indicator is verified and installed, the next
step is to add the Backtest EZ indicator on a daily data series. At the
Long Entry and Long Exit field, type in the corresponding formulas (Listing
3), set all other settings according to the criteria in the article, and
hit Apply to get the system testing results (Figure 8).
FIGURE 8: NEOTICKER, VOLUME FLOW INDICATOR. Hit Apply
to get the system testing results.
Test 3: Break from base (indicator direction and level)
This test can be done simply with the standard VFI indicator along
with formula code in the Backtest EZ Long Entry and Long Exit fields (Listing
4). When adding Backtest EZ, fill in the entry and exit rule and set the
system setting according to the article to get the system results (Figure
9).
FIGURE 9: NEOTICKER, VOLUME FLOW INDICATOR. When adding
Backtest EZ, fill in the entry and exit rule and set the system setting
according to the article to get the system results.
Test 4: Indicator direction
The last test can be done with the standard VFI indicator and formula
code in the Backtest EZ entry and exit field (Listing 5). Complete the
remaining settings in the system tab, and hit Apply to get the testing
result.
Listing 1
Long Entry: xaboveconst(VFI.Plot2(0,data1,26,0.2,2.5,7),0)
Long Exit: xbelowconst(VFI.Plot2(0,data1,26,0.2,2.5,7),0)
Listing 2
$D1 := if(param1 > 200, 200, if(param1 < 2, 2, param1));
P1 := VFI(0,data1,130,0.2,2.5,3) +
absvalue(lowest(VFI(0,data1,130,0.2,2.5,3))) + 10;
LRSI := linslope(0,P1,$D1)/absvalue(P1($D1))*100;
LRS := linslope(0,data1,$D1)/absvalue(data1($D1))*100;
myDiverg := (LRSI-LRS);
plot1 := qc_xaverage(myDiverg, 3)*100;
plot2 := LRSI;
Listing 3
Long Entry: (diverg(1,data1,120)>100) and (diverg(0,data1,120)<diverg(1,data1,120))
and (diverg.Plot2(0,data1,120)>0)
Long Exit: (diverg(0,data1,120)<0) and (diverg.Plot2(0,data1,120)<0)
Listing 4
Long Entry: (VFI(0,data1,130,0.2,2.5,3) > -2)
and (linslope(VFI(0,data1,130,0.2,2.5,3),20)>0.1)
and (VFI(0,data1,130,0.2,2.5,3)>qc_xaverage(VFI(0,data1,130,0.2,2.5,3),40))
and (linslope(c,30)<(c(30)*0.6/100)) and (linslope(c,30)>0)
Long Exit: (VFI(0,data1,130,0.2,2.5,3) < -2) or
(linslope(VFI(0,data1,130,0.2,2.5,3),20) < -0.8)
Listing 5
Long Entry: xabove (qc_xaverage (VFI(0,data1,130,0.2,2.5,3), 11),
qc_xaverage (VFI(0,data1,130,0.2,2.5,3), 25))
Long Exit: xbelow (qc_xaverage (VFI(0,data1,130,0.2,2.5,3), 11),
average (VFI(0,data1,130,0.2,2.5,3), 25))
A package file that contains a group of charts showing all four
testing Backtest EZ indicators along with the formula language indicators
will be available for download from TickQuest's website as well as the
Yahoo! NeoTicker user group file area at https://groups.yahoo.com/group/neoticker/.
--Kenneth Yuen, TickQuest Inc.
www.tickquest.com
GO BACK
STOCKWIZ: VFI PERFORMANCE
Here is the StockWiz formula for backtesting the volume flow indicator
(VFI). This formula is based on test 4 in Markos Katsanos' article in this
issue, "Volume Flow Indicator Performance."
The program tests all the companies in your working group. The formula
calculates the 15- and 80-day simple moving averages of the volume flow
indicator for each company and issues buy signals (if the 15-day SMA rises
above the 80-day SMA) and sell signals (if the 15-day SMA falls below the
80-day SMA).
We start with the first 300 prices and then we move forward the time
frame under study two weeks or 10 business days at a time. For each time
frame, we check our system and buy or sell the current company based on
the trading rules discussed in the previous paragraph.
(CLEAR)
(GRIDFIELD "Ticker" "STRING" "10")
(GRIDFIELD "Name" "STRING" "20")
(GRIDFIELD "StartingAmount" "FLOAT" "0")
(GRIDFIELD "EndingAmount" "FLOAT" "0")
(GRIDFIELD "NumOfTrades" "FLOAT" "0")
(GRIDFIELD "VFIsystemPerformance" "FLOAT" "0")
(GRIDFIELD "BuyHoldPerformance" "FLOAT" "0")
# Load the first company in the worksheet
(SOURCE "WORKING_GROUP")
(SET I 0)
(SET STATUS (LOADFIRST))
(GOTO %TOP (EQ STATUS 0))
(GOTO %ERROR (TRUE))
# Load data for the current company
%TOP:
(SET HIGH (GETVECTOR (CURRENT) "HIGH"))
(SET LOW (GETVECTOR (CURRENT) "LOW"))
(SET CLOSE (GETVECTOR (CURRENT) "CLOSE"))
(SET VOLUME (GETVECTOR (CURRENT) "VOLUME"))
# We start trading each company with $10,000 in cash.
# Fees are $10 per trade.
(SET PRINCIPAL 10000.0)
(SET CASH PRINCIPAL)
(SET SHARES 0.0)
(SET COMMISSION 0.0)
(SET TRADES 0.0)
(SET VALUE 0.0)
(SET COSTPERTRADE 10.0)
# Skip over this company if not enough data is available
(SET LASTDATE (LASTDATE))
(GOTO %NEXT (ISVNA CLOSE))
(GOTO %NEXT (LT (VSIZE CLOSE) 300))
(GOTO %NEXT (BADDATA CLOSE LASTDATE))
(GOTO %EXIT (ESCAPE))
# Calculate the Volume Flow Indicator
(SET TP0 (EVAL CLOSE "(High(i)+Low(i)+Close(i))/3.0"))
(SET TP_current (EVAL CLOSE "(LOG TP0(i))"))
(SET TP1 (EVAL CLOSE "(High(i-1)+Low(i-1)+Close(i-1))/3.0"))
(SET TP_previous (EVAL CLOSE "(LOG TP1(i))"))
(SET TPL (VSUB TP_current TP_previous))
(SET CUT (VSMUL CLOSE (STDDEV TPL)))
(SET CUTOFF (VSMUL CUT 0.2))
(SET TP_chg (VSUB TP0 TP1))
(SET D (VSIZE CLOSE))
%AGAIN1:
(SET T (VSIZE TP_chg))
(SET T (SUB T D))
(SET TP_chg-i (VGET TP_chg T))
(SET C (VSIZE CUTOFF))
(SET C (SUB C D))
(SET CUTOFF-i (VGET CUTOFF C))
(GOTO %STEP1 (GT TP_chg-i CUTOFF-i))
(GOTO %STEP2 (LT TP_chg-i CUTOFF-i))
(GOTO %STEP3 (EQ TP_chg-i CUTOFF-i))
%STEP1: (SET VOL VOLUME)
(GOTO %AGAIN2 (TRUE))
%STEP2: (SET VOL (VSMUL VOLUME -1.0))
(GOTO %AGAIN2 (TRUE))
%STEP3: (SET VOL (VSMUL VOLUME 0.0))
(GOTO %AGAIN2 (TRUE))
%AGAIN2:
(SET D (SUB D 1))
(GOTO %AGAIN1 (GT D 0.0))
(GOTO %SUM (EQ D 0.0))
%SUM:
(SET isize (VSIZE VOL))
(SET i 1)
(SET VLM CLOSE)
%AGAIN:
(VSET VLM i (ADD (VGET VLM (SUB i 1)) (VGET VOL i)))
(SET i (ADD i 1))
(GOTO %AGAIN (LT i isize))
(SET VOL_MA (SHIFTR (MOVAVG VOLUME 50) 1))
(SET VFI (EMOVAVG (VDIV VLM VOL_MA) 3))
# Load the first range for the working vector. We check the
# VFI data for the first 300 trading days.
(SET R1 (BEGDATE CLOSE))
(SET R2 (DATEBADD R1 300))
%NEXTD:
(SET R1 (DATEBSUB R2 300))
(SET WV (VEC2VEC CLOSE R1 R2))
(SET VFI-N (VEC2VEC VFI R1 R2))
# Show a progress report to the user
(SET LASTCLOSE (LAST WV))
(SET VALUE (MUL SHARES LASTCLOSE))
(SET TOTAL (ADD CASH VALUE))
(SET TICKER (CURRENT))
(SET MESSAGE TICKER)
(STATUSBAR 1 MESSAGE)
(GOTO %EXIT (ESCAPE))
# The trading rules: buy shares when the 15-day SMA of the
# VFI is above the 80-day SMA and sell when the opposite
# condition exists.
(SET SMA15 (MOVAVG VFI-N 15))
(SET LAST_SMA15 (LAST SMA15))
(SET SMA80 (MOVAVG VFI-N 80))
(SET LAST_SMA80 (LAST SMA80))
(GOTO %BUY (GT LAST_SMA15 LAST_SMA80))
(GOTO %SELL (LE LAST_SMA15 LAST_SMA80))
(GOTO %SHIFT (TRUE))
# Buy trade
%BUY:
(GOTO %SHIFT (LE CASH LASTCLOSE))
(SET SHARESTOBUY (DIV CASH LASTCLOSE))
(SET SHARES (ADD SHARES SHARESTOBUY))
(SET TRADES (ADD TRADES 1))
(SET COMMISSION (ADD COMMISSION COSTPERTRADE))
(SET CASH (SUB CASH COMMISSION))
(SET CASH 0.0)
(GOTO %SHIFT (TRUE))
# Sell trade
%SELL:
(GOTO %SHIFT (LE SHARES 0.0))
(SET TRADES (ADD TRADES 1))
(SET COMMISSION (ADD COMMISSION COSTPERTRADE))
(SET COST (MUL LASTCLOSE SHARES))
(SET CASH (SUB CASH COMMISSION))
(SET CASH (ADD CASH COST))
(SET SHARES 0.0)
(GOTO %SHIFT (TRUE))
# Add two weeks (ten business days) to our working range
%SHIFT:
(SET R2 (DATEBADD R2 10))
(SET POINTS (BDAYS (BEGDATE CLOSE) R2))
(GOTO %NEXTD (LE POINTS (VSIZE CLOSE)))
# Write the output data to the columns in the worksheet
(GRID TICKER "Name" (GETSTRING "NAME"))
(GRID TICKER "StartingAmount" (DBL2STR PRINCIPAL 0))
(GRID TICKER "EndingAmount" (DBL2STR TOTAL 0))
(GRID TICKER "NumOfTrades" (DBL2STR TRADES 0))
(SET PL1 (PERCENT TOTAL PRINCIPAL))
(SET P-L (SUB PL1 100.0))
(GRID TICKER "VFIsystemPerformance" (DBL2STR P-L 2))
(SET INITIAL (VGET CLOSE 0))
(GOTO %NEXT (EQ INITIAL 0.0))
(SET LC (VSIZE CLOSE))
(SET LC (SUB LC 1))
(SET LASTCL (VGET CLOSE LC))
(SET BH (DIV LASTCL INITIAL))
(SET BH (SUB BH 1))
(SET B-H (MUL BH 100))
(GRID TICKER "BuyHoldPerformance" (DBL2STR B-H 2))
# Exit the program if the user clicks on the 'Cancel' button
(GOTO %EXIT (ESCAPE))
# Load the next company in the worksheet
%NEXT:
(SET STATUS (LOADNEXT))
(SET I (ADD I 1))
(GOTO %TOP (EQ STATUS 0))
%ERROR: (MESSAGE "An error has occurred - Unable to continue")
%EXIT: (EXIT STATUS)
