January 2010

TRADESTATION: VORTEX INDICATOR

Etienne Botes and Douglas Siepman’s article in this issue, “The Vortex Indicator,” describes an indicator intended to identify price trends. The authors include some trading rules. Code for the indicator and for a strategy based on the trading rules is shown here.

Both the indicator and strategy use a parameter named length to define the number of price bars over which to perform certain calculations. The strategy also uses a trailing stop factor, which is the number of average true ranges at which to trail an exit stop order.

To download the adapted EasyLanguage code, go to the TradeStation and EasyLanguage Support Forum (https://www.tradestation.com/Discussions/forum.aspx?Forum_ID=213). Search for the file “Vortex.eld.”

A sample chart is shown in Figure 1.

Figure 1: TRADESTATION, VORTEX INDICATOR. Here is an example of the Vortex Indicator and strategy applied to a daily chart of SPY.

Indicator:  Vortex
inputs:
	Length( 14 ) ;

variables:
	VMPlus( 0 ),
	VMMinus( 0 ),
	VMPlusSum( 0 ),
	VMMinusSum( 0 ),
	TR( 0 ),
	TRSum( 0 ),
	VIPlusSumRge( 0 ),
	VIMinusSumRge( 0 ) ;

VMPlus = AbsValue( High - Low[1] ) ;
VMMinus = AbsValue( Low - High[1] ) ;
VMPlusSum = Summation( VMPlus, Length ) ;
VMMinusSum = Summation( VMMinus, Length ) ;
TR = TrueRange ;
TRSum = Summation( TR, Length ) ;

if TRSum <> 0  then
	begin
	VIPlusSumRge = VMPlusSum / TRSum ;
	VIMinusSumRge = VMMinusSum / TRSum ;
	end ;

Plot1( VIPlusSumRge, "VI+Sum/Rge", Green ) ;
Plot2( VIMinusSumRge, "VI-Sum/Rge", Red ) ;

Strategy:  VortexStrat
inputs:
	Length( 14 ),
 	StopFactor( 2 ) ; { number of true ranges }

variables:
	VMPlus( 0 ),
	VMMinus( 0 ),
	VMPlusSum( 0 ),
	VMMinusSum( 0 ),
	TR( 0 ),
	TRSum( 0 ),
	VIPlusSumRge( 0 ),
	VIMinusSumRge( 0 ),
	SignalTradeNum( 0 ),
	BuySignal( false ),
	ShortSignal( false ),
	StopPrice( 0 ) ;

VMPlus = AbsValue( High - Low[1] ) ;
VMMinus = AbsValue( Low - High[1] ) ;
VMPlusSum = Summation( VMPlus, Length ) ;
VMMinusSum = Summation( VMMinus, Length ) ;
TR = TrueRange ;
TRSum = Summation( TR, Length ) ;

if TRSum <> 0  then
	begin
	VIPlusSumRge = VMPlusSum / TRSum ;
	VIMinusSumRge = VMMinusSum / TRSum ;
	end ;

if VIPlusSumRge crosses over VIMinusSumRge then
	begin
	SignalTradeNum = TotalTrades ;
	BuySignal = true ;
	ShortSignal = false ; 
	StopPrice = High ;
	end 
else if VIPlusSumRge crosses under VIMinusSumRge then
	begin
	SignalTradeNum = TotalTrades ;
	BuySignal = false ;
	ShortSignal = true ; 
	StopPrice = Low ;
	end ;

if BuySignal and TotalTrades = SignalTradeNum and
 MarketPosition <> 1 then
	Buy next bar StopPrice stop ;

if ShortSignal and TotalTrades = SignalTradeNum and
 MarketPosition <> -1 then
	SellShort next bar at StopPrice stop ;

SetStopShare ;
SetDollarTrailing( TR * StopFactor ) ;

This article is for informational purposes. No type of trading or investment recommendation, advice, or strategy is being made, given, or in any manner provided by TradeStation Securities or its affiliates.

—Mark Mills
TradeStation Securities, Inc.
A subsidiary of TradeStation Group, Inc.
www.TradeStation.com

BACK TO LIST

WEALTH-LAB: VORTEX INDICATOR

This Traders’ Tip is based on “The Vortex Indicator” by Etienne Botes and Douglas Siepman in this issue.

We’ve added the Vortex Indicator to our TascIndicators library for easy reference and also programmed a stop & reverse version of the trading strategy suggested by Botes and Siepman using an Atr trailing stop. On the S&P emini, the strategy was effective in entering and remaining in large trends, garnering more than $33,000 in profits trading two contracts 24 times over the past two years (no slippage or commissions). As typically observed when using stops, tightening the stop by reducing the Atr factor reduced trading profit. See Figure 3 for a sample chart.

Figure 3: WEALTH-LAB, VORTEX INDICATOR. The strategy to reverse on a stop was effective in remaining in strong trends despite multiple crossings of the Vortex Indicator.

WealthScript Code (C#): 

using System;
using System.Collections.Generic;
using System.Text;
using System.Drawing;
using WealthLab;
using WealthLab.Indicators;
using TASCIndicators;

namespace WealthLab.Strategies
{
   public class MyStrategy : WealthScript
   {
      //Pushed indicator StrategyParameter statements
      private StrategyParameter vmPeriod;
      private StrategyParameter atrFactor;

      public MyStrategy()
      {
         vmPeriod = CreateParameter("VM Period",14,5,100,10);
         atrFactor = CreateParameter("ATR Factor",4,1,5,0.5);

      }
      protected override void Execute()
      {   
         int period = vmPeriod.ValueInt;
         int xBar = 0;      // Crossing bar or stop bar   
         bool bull = false;
         double triggerPrice = -1d;
         double stopPrice = -1d;         
         
         DataSeries vmPlus = VMPlus.Series(Bars ,period);
         DataSeries vmMinus = VMMinus.Series(Bars ,period);
         DataSeries atr = atrFactor.Value * ATR.Series(Bars, 10);
         ChartPane paneVM = CreatePane(40,true,true);
         PlotSeries(paneVM, vmPlus, Color.Blue, LineStyle.Solid, 2);
         PlotSeries(paneVM, vmMinus, Color.Red, LineStyle.Solid, 2);
         PlotStops();
         HideVolume();
         
         for(int bar = period; bar < Bars.Count; bar++)
         {
            if (CrossOver(bar, vmPlus, vmMinus))
            {
               SetBackgroundColor(bar, Color.LightBlue);
               bull = true;
               xBar = bar;
            }
            else if (CrossUnder(bar, vmPlus, vmMinus))
            {
               SetBackgroundColor(bar, Color.LightPink);
               bull = false;
               xBar = bar;
            }
            
            if (IsLastPositionActive)
            {
               Position p = LastPosition;
               if (p.PositionType == PositionType.Long)
               {
                  if (!bull)
                  {
                     SellAtStop(bar + 1, p, Low[xBar]);
                     ShortAtStop(bar + 1, Low[xBar]);
                  }
                  else if (SellAtTrailingStop(bar + 1, p, Close[bar] - atr[bar], "T-Stop"))
                     xBar = bar + 1;
               }
               else
               {
                  if (bull)
                  {
                     CoverAtStop(bar + 1, p, High[xBar]);
                     BuyAtStop(bar + 1, High[xBar]);
                  }
                  else if (CoverAtTrailingStop(bar + 1, p, Close[bar] + atr[bar], "T-Stop"))
                     xBar = bar + 1;
               }               
            }
            else if (xBar > period) // initial and re-entry
            {               
               if (bull) BuyAtStop(bar + 1, High[xBar]);
               else ShortAtStop(bar + 1, Low[xBar]);
            }
         }
      }
   }
}

— Robert Sucher
www.wealth-lab.com

BACK TO LIST

WORDEN BROTHERS STOCKFINDER: VORTEX INDICATOR

The Vortex Indicator described in Etienne Botes and Douglas Siepman’s article in this issue, “The Vortex Indicator,” has now been added to the library of indicators available in StockFinder.

You can add the indicator to your chart in StockFinder (Figure 5) by clicking the “Add indicator” button or by simply typing “/Vortex Indicator” and choosing it from the filtered list of available indicators.

Figure 5: STOCKFINDER, VORTEX INDICATOR

We have written the Vortex Indicator code in RealCode, which is based on the Microsoft Visual Basic.Net framework and uses the Visual Basic (VB) language syntax. RealCode is compiled into a .Net assembly and run by the StockFinder application. Unlike the scripting language that other trading applications use, RealCode is fully compiled and runs at the same machine-language level as the application itself. This gives you unmatched performance, with the flexibility of “run-time development and assembly” that you get by writing your own custom code.

Here is the code for the Vortex Indicator:

'# Period = UserInput.Integer = 14
Static pVM As Single
Static nVM As Single
Static ATR As Single
If CurrentIndex > Period Then
	pVM += (System.Math.Abs(Price.High - Price.Low(1)) - System.Math.Abs(Price.High(Period)
- Price.Low(Period + 1))) / Period
	nVM += (System.Math.Abs(Price.Low - Price.High(1)) - System.Math.Abs(Price.Low(Period)
- Price.High(Period + 1))) / Period
	ATR += (System.Math.Max(Price.High, Price.Last(1)) - System.Math.Min(Price.Low, Price.Last(1))
- System.Math.Max(Price.High(Period), Price.Last(Period + 1)) 
+ System.Math.Min(Price.Low(Period), Price.Last(Period + 1))) / Period
Else If isFirstBar Then
	pVM = 0
	nVM = 0
	ATR = 0
Else
	pVM += System.Math.Abs(Price.High - Price.Low(1)) / Period
	nVM += System.Math.Abs(Price.Low - Price.High(1)) / Period
	ATR += (System.Math.Max(Price.High, Price.Last(1)) - System.Math.Min(Price.Low, Price.Last(1))) / Period
End If
If ATR > 0 Then
	Dim pVMnorm As Single = pVM / ATR
	Dim nVMnorm As Single = nVM / ATR
	OpenValue = nVMnorm
	HighValue = System.Math.Max(pVMnorm, nVMnorm)
	LowValue = System.Math.Min(pVMnorm, nVMnorm)
	Plot = pVMnorm
Else
	Plot = Single.NaN
End If

To download the StockFinder software and get a free trial, go to www.StockFinder.com.

— Bruce Loebrich and Patrick Argo
Worden Brothers, Inc.
www.StockFinder.com

BACK TO LIST

NEUROSHELL TRADER: VORTEX INDICATOR

The Vortex Indicator described by Etienne Botes and Douglas Siepman in their article in this issue can be easily implemented in NeuroShell Trader by combining a few of NeuroShell Trader’s 800+ indicators. First, select “New Indicator” from the Insert menu and use the Indicator Wizard to create the following indicators:

+VM:	Abs( Subtract( High, Lag( Low, 1 ) ) )

-VM:	Abs( Subtract( Low, Lag( High, 1 ) ) )

TR:	Max3( Subtract( High, Low ), 
Abs( Subtract( High, Lag( Close, 1) ) ), 
Abs( Subtract( Low, Lag( Close, 1 ) ) ) )

VI+:	Divide( Sum( +VM, 14 ), Sum( TR, 14 ) )

VI-:	Divide( Sum( -VM, 14 ), Sum( TR, 14 ) )

Then, to create a trading system based on the Vortex Indicator, select “New Trading Strategy” from the Insert menu and enter the following in the appropriate locations of the Trading Strategy Wizard:

Generate a buy long STOP when all of the following conditions are true:

	A>B ( VI+, VI- )

Stop price: 

	SelectiveMovAvg ( High, CrossAbove( VI+, VI-), 1 )

Generate a short sell STOP when all of the following conditions are true:

	A<B ( VI+, VI- )

Stop price: 

	SelectiveMovAvg ( Low, CrossBelow( VI+, VI-), 1 )

If you have NeuroShell Trader Professional, you can also choose whether the system parameters should be optimized. After backtesting the trading strategy, use the “Detailed Analysis” button to view the backtest and trade-by-trade statistics for the system.

A sample chart is shown in Figure 7.

Figure 7: NEUROSHELL TRADER, VORTEX INDICATOR. Here is a demonstration of a system based on the Vortex Indicator on the QQQQ.

—Marge Sherald, Ward Systems Group, Inc.
301 662-7950, sales@wardsystems.com
www.neuroshell.com

BACK TO LIST

TRADERSSTUDIO: VORTEX INDICATOR

The TradersStudio code is given here for the Vortex Indicator (VI), function, and system from the article in this issue, “The Vortex Indicator,” by Etienne Botes and Douglas Siepman.

The coded version that I have supplied also includes a system that can be used to test the indicator against J. Wells Wilder’s original directional movement index (Dmi). The system uses only the VI (or Dmi) and is based on crossovers of the VI (or Dmi). The rules for the system are:

1. Go long when the VI (or Dmi) goes from less than zero to greater than zero.
2. Go short when the VI (or Dmi) goes from above zero to less than zero.
3. All trades are placed “next day market on open.”

The system is always in the market either long or short. To test the indicator, I created a portfolio of 38 of the more actively traded, full-sized futures contracts. I used back-adjusted data (day session only) from Pinnacle Data for the following symbols: AD, BO, BP, C, CC, CD, CL, CT, DJ, DX, ED, FA, FC, FX, GC, HG, HO, HU, JO, JY, KC, KW, LC, LH, NG, NK, PB, RB, S, SB, SF, SI, SM, SP, TA, TD, UA, W.

A comparative test of the Vortex Indicator versus the original Dmi is shown on a year-by-year basis in the table in Figure 10. The test runs from 1978 to November 6, 2009. The years and metrics where the VI outperformed the Dmi are highlighted in light green. Over the entire test period and within the last 10 years, the VI shows a better performance than Wilder’s original Dmi when tested on this portfolio of futures markets using the 14-day parameter.

Figure 10: TRADERSSTUDIO, VORTEX INDICATOR (VI) VS. DIRECTIONAL MOVEMENT INDEX (DMI), FUTURES, 1978—2009. This table shows a year-by-year comparison of the VI versus the DMI on a portfolio of 38 futures contracts trading one contract per trade. Light-green shaded areas highlight which indicator had the better performance.

I also ran a comparative test using 101 Nasdaq stocks over the period 1992 to 8/14/2009. These stocks were chosen based on high liquidity and high volatility and have similar characteristics to the stocks in the Nasdaq 100 index. Using this list of Nasdaq stocks showed the opposite results from the futures test in that the Dmi showed more profit and a higher mean to standard deviation ratio than the VI. This test on stocks is shown in Figure 11. These contradictory results indicate that further tests should be run.

Figure 11: TRADERSSTUDIO, VORTEX INDICATOR (VI) VS. DIRECTIONAL MOVEMENT INDEX (DMI), STOCKS, 1978—2009. This table shows a year-by-year comparison of the VI versus the DMI on a portfolio of 101 high-liquidity NASDAQ stocks trading 100 shares per trade. Light-green shaded areas highlight which indicator had the better performance.

The code can be downloaded from the TradersStudio website at www.TradersStudio.com →Traders Resources→FreeCode and also from www.TradersEdgeSystems.com/traderstips.htm.

' THE VORTEX INDICATOR SYSTEM
' Authors: Etienne Botes & Douglas Siepman, TASC January 2010
' Coded by: Richard Denning 11/06/09
' www.TradersEdgeSystems.com

Sub VORTEX_SYS(vLen, useVortex)
' defaults: vLen = 14, useVortex = 1 (if set to <> 1 system 
'   uses the original Wells Wilder DMI indicator) 
Dim VI As BarArray
Dim VIp 
Dim VIm
Dim DMI As BarArray 

If useVortex = 1 Then
    VI = VORTEX_INDEX(VIp,VIm,vLen)
    If VI > 0 And VI[1] < 0 Then Buy("LE_VORTEX",1,0,Market,Day)
    If VI < 0 And VI[1] > 0 Then Sell("SE_VORTEX",1,0,Market,Day)
Else
    DMI = DMIplus(vLen,0) - DMIminus(vLen,0)
    If DMI > 0 And DMI[1] < 0 Then Buy("LE_DMI",1,0,Market,Day)
    If DMI < 0 And DMI[1] > 0 Then Sell("SE_DMI",1,0,Market,Day)
End If

End Sub
'---------------------------------------------------------------------
' THE VORTEX INDICATOR MULTI-OUTPUT FUNCTION
Function VORTEX_INDEX(ByRef VIp, ByRef VIm, vorLen)
    Dim sumVMplus 
    Dim sumVMminus 
    Dim sumTR 
    Dim VIplus 
    Dim VIminus 
    
    sumVMplus = summ(Abs(H - L[1]),vorLen)
    sumVMminus = summ(Abs(H[1] - L),vorLen)
    sumTR = summ(TrueRange,vorLen)
    If sumTR <> 0 Then
        VIplus = sumVMplus / sumTR
        VIminus = sumVMminus / sumTR
    End If
    VIp = VIplus
    VIm = VIminus
    VORTEX_INDEX = VIp - VIm
End Function
'---------------------------------------------------------------------
'THE VORTEX PLUS INDICATOR FUNCTION
Function VORTEX_PLUS(vorLen)
    Dim sumVMplus As BarArray
    Dim sumTR As BarArray
    
    sumVMplus = summ(Abs(H - L[1]),vorLen)
    sumTR = summ(TrueRange,vorLen)
    If sumTR <> 0 Then
        VORTEX_PLUS = sumVMplus / sumTR
    End If
End Function
'---------------------------------------------------------------------
'THE VORTEX MINUS INDICATOR FUNCTION
Function VORTEX_MINUS(vorLen)
    Dim sumVMminus As BarArray
    Dim sumTR As BarArray
    
    sumVMminus = summ(Abs(H[1] - L),vorLen)
    sumTR = summ(TrueRange,vorLen)
    If sumTR <> 0 Then
        VORTEX_MINUS = sumVMminus / sumTR
    End If  
End Function
'---------------------------------------------------------------------
'THE VORTEX INDICATOR (FOR CHART DISPLAY)
sub VORTEX_IND(viLen)
    plot1(VORTEX_PLUS(viLen))
    plot2(VORTEX_MINUS(viLen))
End Sub
'---------------------------------------------------------------------

—Richard Denning
richard.denning@earthlink.net
for TradersStudio

BACK TO LIST

TRADECISION: VORTEX INDICATOR

The article by Etienne Botes and Douglas Siepman in this issue, “The Vortex Indicator,” demonstrates a technical indicator for trading a change in market direction. The Vortex Indicator was developed as a new type of directional movement indicator by drawing inspiration from J. Welles Wilder’s original directional movement index (Dmi) as well as from Viktor Schauberger’s study of the vortex motions of water.

To implement the VI in Tradecision, use the Indicator Builder to set up two indicators: Vortex Indicator Plus and Vortex Indicator Minus. Here is the Tradecision code for the Vortex Indicator Plus:

Vortex Indicator Plus:
input
 Length:"Length",14;
end_input

 var
 VMPlus:=0;
 VMPlusS:=0;
 VMTR:=0;
 VMTRS:=0;
 VIPlus:=0;
 end_var

 VMPlus:= Abs(High - Low\1\);
 VMPlusS:=CumSum(VMPlus,Length);

 VMTR:= Max(VMPlus, Abs(High - Close\1\), Abs(Low - Close\1\));  VMTRS:=CumSum(VMTR,Length);

 VIPlus:= VMPlusS/VMTRS;

 return VIPlus;

Here is the Tradecision code for the Vortex Indicator Minus:

Vortex Indicator Minus:
input
 Length:"Length",14;
end_input

 var
 VMPlus:=0;
 VMMinus:=0;
 VMMinusS:=0;
 VMTR:=0;
 VMTRS:=0;
 VIMinus:=0;
 end_var

 VMPlus:= Abs(High - Low\1\);
 VMMinus:=Abs(Low - High\1\);
 VMMinusS:=CumSum(VMMinus,Length);

 VMTR:= Max(VMPlus, Abs(High - Close\1\), Abs(Low - Close\1\));  VMTRS:=CumSum(VMTR,Length);

 VIMinus:= VMMinusS/VMTRS;

 return VIMinus;

To import the strategy into Tradecision, visit the area “Traders' Tips from Tasc Magazine” at www.tradecision.com/support/tasc_tips/tasc_traders_tips.htm or copy the code from the Stocks & Commodities website at www.traders.com. A sample chart implementation is shown in Figure 13.

FIGURE 13: TRADECISION, 14-PERIOD DAILY VORTEX INDICATOR PLOTTED ON AN XOM DAILY CHART. +VI and -VI converge and diverge in relation to one another and sometimes intersect each other. The crossing points are the potential trend change points.

—Yana Timofeeva, Alyuda Research
510 931-7808, sales@tradecision.com
www.tradecision.com

BACK TO LIST

NEOTICKER: VORTEX INDICATOR

The Vortex Indicator as presented by Etienne Botes and Douglas Siepman in their article in this issue can be implemented in NeoTicker as a formula language indicator (Listing 1) with period as a parameter. This parameter will allow users to easily adjust the period on which the Vortex Indicator is calculated. The Vortex Indicator will return VI+ and VI- calculations and plot the values in separate panes on the chart (Figure 14).

Within the indicator code, I substituted a direct true range calculation as shown in the article’s Excel sidebar with the built-in truerange. This will improve execution speed and efficiency of the indicator. SafeDiv is a formula function that avoids a division-by-zero error.

Figure 14: NEOTICKER, VORTEX INDICATOR. The NeoTicker indicator code will return a VI+ and VI- calculation and plot the values in separate panes on the chart.

A downloadable version of the indicator and a sample system implementation using the Vortex Indicator will be available in the NeoTicker blog (https://blog.neoticker.com).

LISTING 1

VMPlus  := absvalue(high-low(1));
VMMinus := absvalue(low-high(1));
$TR_sum := summation(truerange(data1), param1);
$VMPlus_sum := summation(VMPlus, param1);
$VMMinus_sum := summation(VMMinus, param1);
plot1 := SafeDiv($VMPlus_sum,  $TR_sum, 0);
plot2 := SafeDiv($VMMinus_sum, $TR_sum, 0);

—Kenneth Yuen
TickQuest, Inc.
www.neoticker.com

BACK TO LIST

WAVE59: VORTEX INDICATOR

In their article in this issue, “The Vortex Indicator,” Etienne Botes and Douglas Siepman present their Vortex Indicator, an improved version of J. Welles Wilder’s classic indicator, the directional movement index (Dmi).

Figure 16 is a weekly chart of Qqqq showing the Vortex Indicator in action. Note the timely call for a low in March 2009 as well as the very bullish indication since that time. More important, note that the VM+ is preparing to cross under the VM-, which would indicate a change in trend to the downside.

FIGURE 16: WAVE59, VORTEX INDICATOR. Shown is a weekly chart of QQQQ with the Vortex Indicator. Note the timely call for a low in March 2009 as well as the very bullish indication since then. More important, note that the VM+ is preparing to cross under the VM-, which would indicate a change in trend to the downside.

The following script implements this indicator in Wave59. As always, users of Wave59 can download these scripts directly using the QScript Library found at https://www.wave59.com/library.

Indicator:  SC_BotesSiepman_Vortex
input:length(14),plus_color(blue),minus_color(red),thickness(1);

#calculate raw vm+ and vm-
vm_plus = abs(high-low[1]);
vm_minus = abs(low-high[1]);

#sum vm+ and vm-
sum_vm_plus = summation(vm_plus,length);
sum_vm_minus = summation(vm_minus,length);

#calculate true range
sum_tr = summation(truerange(),length);

#divide summed vm+, vm- by summed true range
vm_plus_final = sum_vm_plus/sum_tr;
vm_minus_final = sum_vm_minus/sum_tr;

#plot it
plot1 = vm_plus_final;
plot2 = vm_minus_final;
color1 = plus_color;
color2 = minus_color;
thickness1, thickness2 = thickness;

—Earik Beann
Wave59 Technologies Int’l, Inc.
www.wave59.com

BACK TO LIST

INVESTOR/RT: VORTEX INDICATOR

The Vortex Indicator as described by Etienne Botes and Douglas Siepman in their article in this issue can be implemented in Investor/RT using two custom indicators. The syntax for the +VI custom indicator is simply:

SUM(HI - LO.1, 14) / SUM(TR, 14)

and the syntax for the -VI custom indicator is:

SUM(HI.1 - LO, 14) / SUM(TR, 14)

These calculations are based on a 14-period Vortex Indicator. To change the period, simply change the number “14” to the new period in the two locations it is found in each custom indicator. A chart showing the +VI and -VI on daily bars of the S&P mini contract can be seen in Figure 17.

FIGURE 17: INVESTOR/RT, Vortex Indicator. A 14-period Vortex Indicator is plotted on daily bars of the S&P mini contract. The green line in the lower pane represents the +VI while the red line represents the -VI.

To import a chart containing the Vortex Indicator into Investor/RT, visit https://www.linnsoft.com/charts/VortexIndicator.html

To learn more about creating custom indicators in Investor/RT, visit https://www.linnsoft.com/tutorials/rtl.htm.

—Chad Payne
Linn Software
info@linnsoft.com,
www.linnsoft.com

BACK TO LIST

VT TRADER: VORTEX INDICATOR

Our Traders’ Tip submission is inspired by the article “The Vortex Indicator” by Etienne Botes and Douglas Siepman in this issue. We’ll be offering the Vortex Indicator for download in our online forums.

The VT Trader code and instructions for recreating the indicator are as follows:

1. VT Trader’s Ribbon→Technical Analysis menu→Indicators group→Indicators Builder→[New] button
2. In the General tab, type the following text into each corresponding text box:

   Name: TASC - 01/2010 - Vortex Indicator
   Function Name Alias: tasc_Vortex
   Label Mask: TASC - 01/2010 - Vortex Indicator (%Periods%)
   +VI = %PlusVI%, -VI = %MinusVI%
   Placement: New Frame
   Data Inspection Alias: Vortex
   

3. In the Input Variable(s) tab, create the following variables:

   [New] button...
   Name: Periods	
   Display Name: Periods
   Type: integer
   Default: 13
   
   

4. In the Output Variable(s) tab, create the following variables:

   [New] button...
   Var Name: PlusVI	
   Name: (Plus VI)
   Line Color: blue
   Line Width: slightly thicker
   Line Type: solid
   
   [New] button...
   Var Name: MinusVI	
   Name: (Minus VI)
   Line Color: red
   Line Width: slightly thicker
   Line Type: solid
   

5. In the Formula tab, copy and paste the following formula:

   {Provided By: Capital Market Services, LLC & Visual Trading Systems, LLC}
   {Copyright: 2010}
   {Description: TASC, January 2010 - "Reliability is Harder than it Looks  - The Vortex Indicator" }
   {by Etienne Botes and Douglas Siepman}
   {File: tasc_Vortex.vtscr - Version 1.0}
   
   PlusVM:= abs(H-ref(L,-1));
   MinusVM:= abs(L-ref(H,-1));
   
   SumPlusVM:= sum(PlusVM,Periods);
   SumMinusVM:= sum(MinusVM,Periods);
   
   TrueRange:= max(H-L,max(abs(H-ref(C,-1)),abs(L-ref(C,-1))));
   SumTrueRange:= sum(TrueRange,Periods);
   
   PlusVI:= SumPlusVM/SumTrueRange;
   MinusVI:= SumMinusVM/SumTrueRange;
   

6. Click the “Save” icon in the toolbar to finish building the Vortex Indicator.

To attach the indicator to a chart (Figure 19), click the right mouse button within the chart window and then select “Add Indicator” → “Tasc - 01/2010 - Vortex Indicator” from the indicator list.

Figure 19: VT TRADER, VORTEX INDICATOR. Here is the Vortex Indicator on a one-hour candlestick chart of the EUR/USD.

To learn more about VT Trader, please visit www.cmsfx.com.

Risk disclaimer: Past performance is not indicative of future results. Forex trading involves a substantial risk of loss and may not be suitable for all investors.

—Chris Skidmore
CMS Forex
(866) 51-CMSFX, trading@cmsfx.com
www.cmsfx.com

BACK TO LIST

METASTOCK: VORTEX INDICATOR

The article “The Vortex Indicator” introduces a new indicator and a suggested trading method. Both can be added to MetaStock with the formulas listed below.

I split the indicator into two separate formulas to make it easier to color them correctly. To enter these indicators into MetaStock:

1. In the Tools menu, select Indicator Builder.
2. Click New to open the Indicator Editor for a new indicator.
3. Type the name “Vortex +”.
4. Click in the larger window and paste or type in the formula:
   
   

   tp:= Input("time periods",1,100,14);
   Sum(Abs(H-Ref(L,-1)),tp)/
   Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp)

   
   
5. Click Ok to close the Indicator Editor.
6. Click New to open the Indicator Editor for a new indicator.
7. Type the name “Vortex -”.
8. Click in the larger window and paste or type in the formula:
   
   

   tp:= Input("time periods",1,100,14);
   Sum(Abs(L-Ref(H,-1)),tp)/
   Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp)

   
   
9. Click Ok to close the Indicator Editor.
10. Click Ok to close Indicator Builder.

The system test and instructions for creating it in MetaStock are:

1. Select Tools > the Enhanced System Tester.
2. Click New.
3. Enter a name, “Vortex System”.
4. Select the Buy Order tab and enter the following formula:
   
   

   tp:= 14;
   vip:=Sum(Abs(H-Ref(L,-1)),tp)/
   Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
   vim:=Sum(Abs(L-Ref(H,-1)),tp)/
   Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
   bset:=cross(vip,vim);
   cross(h,valuewhen(1,bset,h))



5. Set the Order Type to Stop.
6. Select the Limit or Stop Price and enter the following formula:
   
   

   tp:= 14;
   vip:=Sum(Abs(H-Ref(L,-1)),tp)/
   Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
   vim:=Sum(Abs(L-Ref(H,-1)),tp)/
   Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
   bset:=cross(vip,vim);
   valuewhen(1,bset,h)



7. Select the Sell Order tab and enter the following formula:
   
   

   tp:= 14;
   vip:=Sum(Abs(H-Ref(L,-1)),tp)/
   Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
   vim:=Sum(Abs(L-Ref(H,-1)),tp)/
   Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
   sset:=cross(vim,vip);
   cross(valuewhen(1,sset,L),L)



8. Set the Order Type to Stop.
9. Select the Limit or Stop Price and enter the following formula:
   
   

   tp:= 14;
   vip:=Sum(Abs(H-Ref(L,-1)),tp)/
   Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
   vim:=Sum(Abs(L-Ref(H,-1)),tp)/
   Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
   sset:=cross(vim,vip);
   valuewhen(1,sset,L)

   
   
10. Select the Sell Short Order tab and enter the following formula:
    
    

    tp:= 14;
    vip:=Sum(Abs(H-Ref(L,-1)),tp)/
    Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
    vim:=Sum(Abs(L-Ref(H,-1)),tp)/
    Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
    sset:=cross(vim,vip);
    cross(valuewhen(1,sset,L),L)

    
    
11. Set the Order Type to Stop.
12. Select the Limit or Stop Price and enter the following formula:
    
    

    tp:= 14;
    vip:=Sum(Abs(H-Ref(L,-1)),tp)/
    Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
    vim:=Sum(Abs(L-Ref(H,-1)),tp)/
    Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
    sset:=cross(vim,vip);
    valuewhen(1,sset,L)

    
    
13. Select the Buy to Cover Order tab and enter the following formula:
    
    

    tp:= 14;
    vip:=Sum(Abs(H-Ref(L,-1)),tp)/
    Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
    vim:=Sum(Abs(L-Ref(H,-1)),tp)/
    Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
    bset:=cross(vip,vim);
    cross(h,valuewhen(1,bset,h))

    
    
14. Set the Order Type to Stop.
15. Select the Limit or Stop Price and enter the following formula:
    
    

    tp:= 14;
    vip:=Sum(Abs(H-Ref(L,-1)),tp)/
    Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
    vim:=Sum(Abs(L-Ref(H,-1)),tp)/
    Sum(Max(H,Ref(C,-1))-Min(L,Ref(C,-1)),tp);
    bset:=cross(vip,vim);
    valuewhen(1,bset,h)

    
    
16. Click OK to close the system editor.

—William Golson
Equis International
www.MetaStock.com

BACK TO LIST